ESP8266を使って自宅外の気象情報を監視する② – ソーラーパネルで動かしてみた

#include <Wire.h>
#include <BH1750.h>
#include <Adafruit_BME280.h>
#include <ESP8266WiFi.h>
#include <ESP8266HTTPClient.h>
#include <WiFiClientSecureBearSSL.h>
#include <time.h>

// LM393
#define RAIN_PIN_A A0
#define RAIN_PIN_D D7
#define RAIN_PIN_V 10

// LED OK/NG by HTTP status
#define LED_OK D5
#define LED_NG D6

// Constant values
#define JST     3600*9
#define BH1750_ADDRRESS 0x23
#define BME280_ADDRESS 0x76
#define SEALEVELPRESSURE_HPA (1013.25)

ADC_MODE(ADC_VCC);

BH1750 lm(BH1750_ADDRRESS);
Adafruit_BME280 bme;

// Wifi Credential
const char* ssid = "ssid";
const char* password = "password";

// Endpoint URL
const char* url = "https://upload-server.example.com";
// 署名証明書 Fingerprint, SHA-1
const uint8_t fingerprint[20] = { 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00 };

// Static IP address 適宜変えてください
IPAddress ip(192, 168, 1, 2); //ip
IPAddress gateway(192,168, 1, 1);
IPAddress subnet(255, 255, 255, 0);
IPAddress dns(192, 168, 1, 1);

void setup() {

  // Initialization
  Serial.begin(9600);
  delay(100);
  Serial.println("Start");

  // Preprocessing
  Wire.begin();
  connect();
  delay(3000);  // NTP時間反映待ち

  // BH1750
  lm.begin(BH1750::CONTINUOUS_HIGH_RES_MODE);
  // BME280
  bme.begin(BME280_ADDRESS);
  // LM393
  pinMode(RAIN_PIN_V, OUTPUT);
  digitalWrite(RAIN_PIN_V, LOW);
  // LEDs setup
  pinMode(LED_OK, OUTPUT);
  pinMode(LED_NG, OUTPUT);

  // Main
  captureAndSendData();

  // Post-processing
  disconnect();
  ESP.deepSleep(600 * 1000 * 1000, WAKE_RF_DEFAULT);  // 10分間deep sleep
  delay(1000); // Deep Sleepモード移行までの待ち

}

void loop() {
}

void captureAndSendData() {

  // 電源電圧取得
  String voltage = String(float(ESP.getVcc()) / 1000);
  Serial.println( "3.3V:>>" + voltage);

  // 実行時間取得, yyyyMMddhhmmss形式
  time_t t;
  struct tm *tm;
  t = time(NULL);
  tm = localtime(&t);

  char dt[14];
  sprintf(dt, "%04d%02d%02d%02d%02d%02d", (tm->tm_year+1900), (tm->tm_mon + 1), tm->tm_mday, tm->tm_hour, tm->tm_min, tm->tm_sec);
  Serial.printf("Date Time: %s\n", dt);

  // BH1750
  float lux = lm.readLightLevel();
  Serial.println("Light: " + String(lux) + " lx");

  // BME280
  float temp = bme.readTemperature();
  float humi = bme.readHumidity();
  double pres = double(bme.readPressure()) / 100;
  double altitude = bme.readAltitude(SEALEVELPRESSURE_HPA);
  Serial.println("Temperature:" + String(temp) + " °C");
  Serial.println("Humidity:" + String(humi) + " %");
  Serial.println("Pressure:" + String(pres) + " hPa");
  Serial.println("Approx. Altitude:" + String(altitude) + " m");

  // LM393
  digitalWrite(RAIN_PIN_V, HIGH);
  boolean raining = !(digitalRead(RAIN_PIN_D));
  if(raining){
    Serial.println("Raining");
  } else{
    Serial.println("No Raining");
  }
  // "ADC_MODE(ADC_VCC)"を使用しない場合は以下でセンサーの電圧を取得
  //int rainVal = analogRead(RAIN_PIN_A);
  //Serial.println("Level:" + String(rainVal));
  digitalWrite(RAIN_PIN_V, LOW);

  // 取得データの送信：JSONで送る場合
  // vo: voltage
  // dt: datetime
  // t:  temperature
  // h:  humidity
  // lx: light intensity
  // p:  pressure
  // alt: approx altitude
  // ir: is raining
  String data = String("") + "{\"vo\":\"" + voltage + "\",\"dt\":\"" + String(dt) + "\",\"t\":\"" + String(temp, 2) + "\",\"h\":\"" + String(humi, 2)
  + "\",\"lx\":\"" + String(lux, 2) + "\",\"p\":\"" + String(pres, 2) + "\",\"alt\":\"" + String(altitude, 2) + "\",\"ir\":\"" + String(raining)
  + "\"}";
  Serial.println("Data: " + data);
  putData(data);

}

void connect () {

  // 静的IPを設定
  WiFi.config(ip, gateway, subnet, dns);
  delay(100);
  WiFi.begin(ssid, password);
  while(WiFi.status() != WL_CONNECTED) {
    Serial.print('.');
    delay(500);
  }
  Serial.println();
  Serial.printf("Connected, IP address: ");
  Serial.println(WiFi.localIP());
  configTime( JST, 0, "ntp.nict.jp", "ntp.jst.mfeed.ad.jp");

}

void disconnect() {

  WiFi.disconnect(true);
  Serial.printf("Disconnected.");

}

void putData (String data) {

  std::unique_ptr<BearSSL::WiFiClientSecure>client(new BearSSL::WiFiClientSecure);
  client->setFingerprint(fingerprint);
  // 証明書チェックを無視する場合はこちらをコメントアウト
  // client->setInsecure();

  HTTPClient https;

  // Reset LED
  digitalWrite(LED_OK, LOW);
  digitalWrite(LED_NG, LOW);
  Serial.print("[HTTPS] begin...\n");

  if (https.begin(*client, url)) {  // HTTPS

    Serial.print("[HTTPS] POST...\n");

    https.addHeader("Content-Type", "application/json; charset=utf8");
    int httpCode = https.POST(data);

    if (httpCode > 0) {
      Serial.printf("[HTTPS] POST... code: %d\n", httpCode);
      String payload = https.getString();
      Serial.println(payload);
      if (httpCode == HTTP_CODE_OK) {
        digitalWrite(LED_OK, HIGH);
        digitalWrite(LED_NG, LOW);
      } else {
        digitalWrite(LED_OK, LOW);
        digitalWrite(LED_NG, HIGH);
      }
    } else {
      Serial.printf("[HTTPS] POST... failed, error: %s\n", https.errorToString(httpCode).c_str());
      digitalWrite(LED_OK, LOW);
      digitalWrite(LED_NG, HIGH);
    }
    https.end();
  } else {
    Serial.printf("[HTTPS] Unable to connect\n");
    digitalWrite(LED_OK, LOW);
    digitalWrite(LED_NG, HIGH);
  }

}