メダカ水槽IoT ESP8266 + WS2812B(LEDテープライト)で照明をコントロールする

#include <Arduino.h>
#include <ESP8266WiFi.h>
#include <ESP8266HTTPClient.h>
#include <WiFiClientSecureBearSSL.h>
#include <time.h>
#include <FastLED.h>
#include <ArduinoJson.h>

#define MAX_NUM_LEDS 16
#define BRIGHTNESS 10
#define DATA_PIN D8
#define JST     3600*9
#define JSON_BUF 4096

const char* ssid = "<ssid>";
const char* password = "<password>";
const char* url = "<設定情報の取得先サーバのエンドポイント>";
// Fingerprint SHA-1, 公開鍵を取得して確認
const uint8_t fingerprint[20] = {0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00};

CRGB tapeLeds[MAX_NUM_LEDS];

void setup() {
  Serial.begin(9600);
  connect();
  // Initialization
  FastLED.addLeds<WS2812B, DATA_PIN, GRB>(tapeLeds, MAX_NUM_LEDS);
  Serial.println("Setup LED tape setting...\n");
  for(int i = 0; i < MAX_NUM_LEDS; i++){
    // Turn the LED on, then pause
    tapeLeds[i] = CRGB::Black;
  }
  FastLED.show();
}

void loop() {
  time_t t;
  struct tm *tm;
  t = time(NULL);
  tm = localtime(&t);
  Serial.printf("%02d:%02d:%02d\n", tm->tm_hour, tm->tm_min, tm->tm_sec);
  refreshLEDLights(tm->tm_hour, tm->tm_min, tm->tm_sec);
  delay(60000);
}

void connect() {
  // WiFi
  WiFi.begin(ssid, password);
  while(WiFi.status() != WL_CONNECTED) {
    Serial.print('.');
    delay(500);
  }
  Serial.println();
  Serial.printf("Connected, IP address: ");
  Serial.println(WiFi.localIP());
  configTime( JST, 0, "ntp.nict.jp", "ntp.jst.mfeed.ad.jp");
}

void refreshLEDLights(int tm_hour, int tm_min, int tm_sec) {
  //Wait for WiFi connection
  if ((WiFi.status() == WL_CONNECTED)) {
    std::unique_ptr<BearSSL::WiFiClientSecure>client(new BearSSL::WiFiClientSecure);
    client->setFingerprint(fingerprint);
    // もし証明書を無視したい場合はこちらを使用する:
    //client->setInsecure();
    HTTPClient https;
    Serial.print("[HTTP] begin...\n");
    if (https.begin(*client, url)) {  // HTTPS
      Serial.print("[HTTP] GET...\n");
      // start connection and send HTTP header
      int httpCode = https.GET();
      // httpCode will be negative on error
      if (httpCode > 0) {
        // HTTP header has been send and Server response header has been handled
        Serial.printf("[HTTP] GET... code: %d\n", httpCode);
        if (httpCode == HTTP_CODE_OK) {
          String payload = https.getString();
          applyLEDLights(tm_hour, tm_min, tm_sec, payload);
        } else {
          Serial.printf("[HTTP] GET... failed, error: %s\n", https.getString());
        }
      } else {
        Serial.printf("[HTTP] GET... failed, error: %s\n", https.errorToString(httpCode).c_str());
      }
      https.end();
    } else {
      Serial.printf("[HTTP] Unable to connect\n");
    }
  } else {
    Serial.printf("[HTTP] WiFi is not conntected...\n");
  }
}

void applyLEDLights (int tm_hour, int tm_min, int tm_sec, String payload) {
  // Deserialize a json payload
  // ref: https://arduinojson.org/v6/assistant/
  DynamicJsonDocument doc(JSON_BUF);
  DeserializationError error = deserializeJson(doc, payload);
  if (error) {
    Serial.print(F("deserializeJson() failed: "));
    Serial.println(error.f_str());
    return;
  }
  int cur_dt = (tm_hour * 10000) + (tm_min * 100) + tm_sec;
  boolean is_found = false;
  Serial.printf("Checking the following current time: %d\n", cur_dt);
  for (JsonObject item : doc.as<JsonArray>()) {
    if (!is_found) {
      // 以下はJSONオブジェクトから必要なものを取得、あくまでも今回の例
      int from_hour = item["from_hour"];
      int from_minute = item["from_minute"];
      int from_second = item["from_second"];
      int to_hour = item["to_hour"];
      int to_minute = item["to_minute"];
      int to_second = item["to_second"];
      int brightness = item["brightness"];
      int leds = item["leds"];
      int color_r = item["color_r"];
      int color_g = item["color_g"];
      int color_b = item["color_b"];

      // Check if the setting is in range of from-to datetime
      int from_dt = (from_hour * 10000) + (from_minute * 100) + from_second;
      int to_dt = (to_hour * 10000) + (to_minute * 100) + to_second;
      if (from_dt <= cur_dt && cur_dt <= to_dt) {
        FastLED.setBrightness(brightness);
        if (MAX_NUM_LEDS < leds) {
          leds = MAX_NUM_LEDS;
        }
        int p = 0;
        for(int i = 0; i < leds; i++){
          tapeLeds[i] = CRGB(color_r, color_g, color_b);
          Serial.printf("%d=on ",i);
          p = i;
        }
        // The rest of leds will be changed to Black
        for(int i = (p + 1); i < MAX_NUM_LEDS; i++){
          tapeLeds[i] = CRGB::Black;
          Serial.printf("%d=off ",i);
        }
        is_found = true;
      }
    }
  }
  FastLED.show();
}

[
    {
        "from_hour": 0,
        "from_minute": 0,
        "from_second": 0,
        "to_hour": 6,
        "to_minute": 59,
        "to_second": 59,
        "brightness": 0,
        "leds": 16,
        "color_r": 0,
        "color_g": 0,
        "color_b": 0
    },
    {
        "from_hour": 7,
        "from_minute": 0,
        "from_second": 0,
        "to_hour": 7,
        "to_minute": 59,
        "to_second": 59,
        "brightness": 32,
        "leds": 16,
        "color_r": 255,
        "color_g": 255,
        "color_b": 255
    }
]